<?xml version="1.0" encoding="utf-8"?>
<s:TitleWindow xmlns:fx="http://ns.adobe.com/mxml/2009" 
           xmlns:s="library://ns.adobe.com/flex/spark" 
           xmlns:mx="library://ns.adobe.com/flex/mx" width="100%"
           height="100%" xmlns:ns1="*"
           creationComplete="creationHandler();" 
           title="报表模板上传"
           close="titlewindow1_closeHandler(event)" 
           xmlns:reporttypewebservice="services.reporttypewebservice.*">
    <fx:Script>
        <![CDATA[
            import cn.com.xxxx.event.PagerCloseEvent;
            import cn.com.xxxx.utils.Constants;
            
            import flash.net.FileReference;
            import flash.net.FileReferenceList;
            
            import mx.collections.ArrayCollection;
            import mx.controls.Alert;
            import mx.core.mx_internal;
            import mx.events.CloseEvent;
            import mx.events.FlexEvent;
            import mx.managers.PopUpManager;
            import mx.rpc.AsyncResponder;
            import mx.rpc.AsyncToken;
            import mx.rpc.events.FaultEvent;
            import mx.rpc.events.ResultEvent;
            
            import valueObjects.Version;
            
            //自定义的关闭事件
            private var pagerCloseEvent:PagerCloseEvent = new PagerCloseEvent();
            
            //选择文件
            private var selectFileList:FileReferenceList = new FileReferenceList(); 
            
            //选择的文件的数组
            [Bindable]
            public var selectedFileArray:ArrayCollection = new ArrayCollection();
            
            //当前版本
            public var currVersion:Version = new Version();
            
            //当前上传文件的下标
            private var currFileIndex:uint = 0;
            
            //上传是否已开始
            [Bindable]
            public var uploadStartFlag:Boolean = false;
            
            //记录上传成功的function，以备删除
            public var lastFunc:Function = null;
            
            private function creationHandler():void{
                
            }
            
            protected function titlewindow1_closeHandler(event:CloseEvent):void
            {
                //上传开始了，不允许关闭
                if(!uploadStartFlag)
                {
                    this.dispatchEvent(pagerCloseEvent);
                    PopUpManager.removePopUp(this);
                }
            }
            
            
            //显示行号
            private function lfRowNum(item:Object, column:int):String
            {
                var index:int=dataGrid.dataProvider.getItemIndex(item) + 1;
                return String(index);
            }

            protected function button1_clickHandler(event:MouseEvent):void
            {
                var fileTypes:FileFilter = new FileFilter("报表模板 (*.xml, *.xsl, *.js)", "*.xml; *.xsl; *.js;");
                var allTypes:Array = new Array( fileTypes );
                
                try
                {
                    selectFileList.browse(allTypes);//不限制类型，就直接browse()即可
                    selectFileList.addEventListener(Event.SELECT, selectHandler1);
                }
                catch (error:Error) 
                {
                    Alert.show("文件选择出现错误，请选择正确的文件");
                }
            }
            
            /**
             * 如果文件被选中,则执行该方法
             * */
            private function selectHandler1(event:Event):void
            {
                //所有文件，放到selectedFileArray中
                var upLoadFileList:FileReferenceList = FileReferenceList(event.target);
                for(var i:int=0;i<upLoadFileList.fileList.length;i++){
                    var f:FileReference = FileReference(upLoadFileList.fileList[i]); 
                    
                    var obj:Object= new Object();
                    obj.fileName = f.name;
                    obj.fileSize = f.size;
                    obj.fileType = f.type;
                    obj.fileRefrence = f;
                    obj.currValue = 0; //已上传字节数
                    obj.uploadOk = false; //是否上传完毕
                    selectedFileArray.addItem(obj);
                }
            }
            
            /**
             * 开始上传.
             * */
            protected function doUpload_clickHandler(event:MouseEvent):void
            {
                currFileIndex = 0;
                uploadStartFlag = true;
                uploadNextFile();
            }
            
            /**
             * 上传下一个文件.
             * */
            protected function uploadNextFile():void
            {
                if(currFileIndex < selectedFileArray.length)
                {
                    //已上传OK，跳过
                    if(selectedFileArray[currFileIndex].uploadOk)
                    {
                        currFileIndex++;
                        uploadNextFile();
                    }
                    else
                    {
                        //载入文件数据
                        var upLoadFile:FileReference = FileReference(selectedFileArray[currFileIndex].fileRefrence); 
                        upLoadFile.addEventListener(Event.COMPLETE,onLoadComplete);
                        upLoadFile.load();
                    }
                    
                }else{
                    uploadStartFlag = false;
                    Alert.show("上传完毕。");
                }
            }
            
            /*
            * 文件数据载入完毕. 
            */
            private function onLoadComplete(e:Event):void
            {
                //主动删除监听器
                var upLoadFile:FileReference = FileReference(e.target);
                upLoadFile.removeEventListener(Event.COMPLETE,onLoadComplete);
                
                //上传数据
                uploadReportTypeFileResult.token = reportTypeWebService.uploadReportTypeFile(currVersion.id,upLoadFile.name,upLoadFile.data);
                
                //一定要删除旧的监听器，否则非常混乱
                if(uploadReportTypeFileResult.hasEventListener(ResultEvent.RESULT))
                {
                    uploadReportTypeFileResult.removeEventListener(ResultEvent.RESULT,lastFunc);
                }
                
                //成功处理
                uploadReportTypeFileResult.addEventListener(ResultEvent.RESULT,
                    function(event:ResultEvent):void 
                    {
                        //记住该function，以备删除
                        lastFunc = arguments.callee;
                        
                        //更新当前上传字节数
                        selectedFileArray[currFileIndex].currValue = upLoadFile.size;
                        selectedFileArray[currFileIndex].uploadOk = true;
                        
                        //下标+1，上传下一个
                        currFileIndex++;
                        uploadNextFile();
                    });
                
                //失败处理
                uploadReportTypeFileResult.addEventListener(FaultEvent.FAULT,
                    function(info:Object):void 
                    {
                        //失败
                        Alert.show(upLoadFile.name);
                        
                        //下标+1
                        currFileIndex++;
                        uploadNextFile();
                    });
            }
        >>
    </fx:Script>
    <fx:Declarations>
        <s:CallResponder id="getReportTypeListResult"/>
        <reporttypewebservice:ReportTypeWebService id="reportTypeWebService" fault="Alert.show(event.fault.faultString + '\n' + event.fault.faultDetail)" showBusyCursor="true"/>
        <s:CallResponder id="uploadReportTypeFileResult"/>
        <!-- 将非可视元素（例如服务、值对象）放在此处 -->
    </fx:Declarations>
    <s:VGroup width="100%"
              height="100%"
              horizontalAlign="left"
              textAlign="left">
            <s:VGroup width="100%"
                      paddingLeft="10"
                      paddingRight="10"
                      height="305">
                
    <mx:DataGrid width="100%" height="300" id="dataGrid" dataProvider="{selectedFileArray}">
        <mx:columns>
            <mx:DataGridColumn labelFunction="lfRowNum" width="40" headerText="序号"/>
            <mx:DataGridColumn headerText="文件名称" dataField="fileName" width="300"/>
            <mx:DataGridColumn headerText="文件大小" dataField="fileSize" width="100"/>
            <mx:DataGridColumn headerText="文件类型" dataField="fileType" width="100"/>
            <mx:DataGridColumn width="300" headerText="状态">
                <mx:itemRenderer>
                    <fx:Component>
                        <mx:HBox width="100%" paddingLeft="2" horizontalGap="2">
                            
                                <fx:Script>
                                    <![CDATA[
                                        import mx.collections.ArrayCollection;
                                        import mx.controls.DataGrid;
                                        import mx.controls.Alert;
                                        
                                        //取消，现在没调用
                                        private function cancel():void{
                                            data.fileRefrence.cancel();
                                            progress.label = "已取消";
                                        }
                                        
                                        //绑定数据时的方法
                                        override public function set data(value:Object):void{
                                            super.data = value; //一定要留着
                                            
                                            //根据currValue显示当前进度
                                            progress.setProgress(data.currValue,data.fileRefrence.size);
                                            
                                            //旧的监听器没用了，删除
                                            if(data.fileRefrence.hasEventListener(ProgressEvent.PROGRESS))
                                            {
                                                data.fileRefrence.removeEventListener(ProgressEvent.PROGRESS,data.func);
                                            }
                                            
                                            //添加新的监听器
                                            data.fileRefrence.addEventListener(ProgressEvent.PROGRESS,progressHandler);
                                            data.func = progressHandler;
                                        }
                                        
                                        //监听进度
                                        private function progressHandler(event:ProgressEvent):void{
                                            trace("equal:"+(event.target==data.fileRefrence));
                                            
                                            //不是当前文件的进度，忽略掉
                                            if(event.target==data.fileRefrence)
                                            {
                                                progress.setProgress(event.bytesLoaded,data.fileRefrence.size);
                                                data.currValue = event.bytesLoaded; //保存进度
                                            }
                                        }

                                        //删除，上传开始后，不让删除，免得下标混乱。
                                        private function deleteItem(data:Object):void {
                                            if(!this.outerDocument.uploadStartFlag)
                                            {
                                                var index:int = this.outerDocument.selectedFileArray.getItemIndex(data);
                                                this.outerDocument.selectedFileArray.removeItemAt(index);
                                            }else{
                                                Alert.show("已开始上传，不能删除。");
                                            }
                                        }
                                    >>
                                </fx:Script>
                            <mx:ProgressBar id="progress" width="100%" label="%3%%"
                                            mode="manual" minimum="0" maximum="{data.fileRefrence.size}"
                                            labelPlacement="center">
                            </mx:ProgressBar>
                            <mx:LinkButton width="20" click="deleteItem(data as Object)" toolTip="从列表中删除" icon="@Embed('assets/delete.gif')">
                            </mx:LinkButton>
                        </mx:HBox>
                    </fx:Component>
                </mx:itemRenderer>
            </mx:DataGridColumn>
        </mx:columns>
    </mx:DataGrid></s:VGroup>
        <s:HGroup width="95%"
                  verticalAlign="middle">
            <mx:Spacer width="50%"/>
            <s:Button label="选择文件" click="button1_clickHandler(event)"/>
            <s:Button id="clearListBtn" label="清空列表" click="selectedFileArray.removeAll()" enabled="{(selectedFileArray.length>0) && (uploadStartFlag==false)}"/>
            <s:Button id="uploadBtn" label="开始上传" click="doUpload_clickHandler(event)" enabled="{(selectedFileArray.length>0) && (uploadStartFlag==false)}"/>
            <s:Button id="closeBtn"
                      label="关闭"
                      click="{dispatchEvent(new CloseEvent(CloseEvent.CLOSE))}"
                      enabled="{uploadStartFlag==false}"/>
        </s:HGroup>
        <s:HGroup width="50%"
                  verticalAlign="middle"
                  height="5">
        </s:HGroup>
        </s:VGroup>
    </s:TitleWindow>

    public void uploadReportTypeFile(String versionId, String fileName,
            byte[] fileData) throws CommonException {
        System.out.println(fileName);
        
    }